开头

  这个工具并没有什么很高的难度在里面，熟悉的大佬可以直接cmd用copy命令编写了。

  不过这个工具的便利在于，可以一个拖拽实现合并，看下图：

代码

@echo off
title 图种生成-斩天及
set /a paramNum=0
if "%~1"=="/?" set paramNum=-1&&goto:Help
if not "%~1"=="" set /a paramNum+=1
if not "%~2"=="" set /a paramNum+=1
if not "%~3"=="" set /a paramNum+=1

if not "%paramNum%"=="2" echo 文件参数个数不正确。&&goto:Help
if not exist "%~1" echo 找不到文件:%~1 &&goto:Help
if not exist "%~2" echo 找不到文件:%~1 &&goto:Help

set picFile=
set rarFile=
set outPutFile=%~dp1图种-%~nx1

if "%~x1"==".jpg" set picFile=%~1
if "%~x1"==".jpeg" set picFile=%~1
if "%~x1"==".bmp" set picFile=%~1
if "%~x1"==".png" set picFile=%~1
if "%~x1"==".rar" set rarFile=%~1
if "%~x1"==".zip" set rarFile=%~1
if "%~x1"==".7z" set rarFile=%~1

if "%~x2"==".jpg" set picFile=%~2
if "%~x2"==".jpeg" set picFile=%~2
if "%~x2"==".bmp" set picFile=%~2
if "%~x2"==".png" set picFile=%~2
if "%~x2"==".rar" set rarFile=%~2
if "%~x2"==".zip" set rarFile=%~2
if "%~x2"==".7z" set rarFile=%~2

if "%picFile%"=="" echo 找不到图片文件。&&goto:Help
if "%rarFile%"=="" echo 找不到压缩文件。&&goto:Help
if "%picFile%"=="%~2" set outPutFile=%~dp2图种-%~nx2

echo 正在生成图种：%outPutFile%
copy /b /y "%picFile%"+"%rarFile%" "%outPutFile%"

goto:eof

:Help
echo+
echo 将1个图片和1个压缩包，打包成1个图种。
echo PickSeed path1 path2
echo+
echo   图片或压缩包路径无先后顺序，如果路径含空格，需要加引号。
echo   生成的图种是以图片的路径加前缀“图种”生成的。
echo   支持的图片格式：.jpg/.jpeg/.bmp/.png
echo   支持的压缩格式：.rar/.zip/.7z
echo+
echo 例如：
echo   pickseed C:\1.jpg C:\2.rar
echo   pickseed C:\3.zip C:\4.png
echo   pickseed "C:\a b c.jpg" "C:\d e f.rar"
echo+
if not "%paramNum%"=="-1" pause

脚本下载

  蓝奏云：https://wwr.lanzoui.com/iBrCxsu3cud

素材来源：吾爱破解